// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © yashp1334

//@version=4
//
// @author LazyBear
//
// This is my custom channel derived from BB/STARC. This uses both ATR/STDEV for plotting the bounds. 
// I use COG for the base line (normally it is SMA/EMA). 
// 
// If you use this code in its original/modified form, do drop me a note. 
//
strategy("COG Double Channel [LazyBear]", shorttitle="COGChannel_LB", overlay=true)
src = close
length = input(34)
median=0
mult=input(2.5)
offset = input(20)
tr_custom() => 
    x1=high-low
    x2=abs(high-close[1])
    x3=abs(low-close[1])
    max(x1, max(x2,x3))
    
atr_custom(x,y) => 
    sma(x,y)
    
dev = (mult * stdev(src, length))
basis=linreg(src, length, median)
ul = (basis + dev)
ll = (basis - dev)
tr_v = tr_custom()
acustom=(2*atr_custom(tr_v, length))
uls=basis+acustom
lls=basis-acustom

buySignal= crossover(lls,src)
sellSignal= crossunder(uls,src)

// Plot STDEV channel
plot(basis, linewidth=1, color=color.navy, title="Median")
lb=plot(ul, color=color.red, linewidth=1, title="BB+")
tb=plot(ll, color=color.green, linewidth=1, title="BB-")
fill(tb,lb, color.silver, title="Region fill")

// Plot ATR channel
plot(basis, linewidth=2, color=color.navy,  title="Median")
ls=plot(uls, color=color.red, linewidth=1, title="Starc+")
ts=plot(lls, color=color.green, linewidth=1, title="Star-")
fill(ts,tb, color.green, title="Region fill")
fill(ls,lb, color.red, title="Region fill")

// Mark SQZ
plot_offs_high=2
plot_offs_low=2 
sqz_f=(uls>ul) and (lls<ll)
b_color=sqz_f ? color.teal : na
plot(sqz_f ? lls-plot_offs_low : na, color=b_color,  linewidth=2)
plot(sqz_f ? uls+plot_offs_high : na, color=b_color, linewidth=2)


//INTRADAY
s=input(title="INTRA DAY TRADE SESSION",type=input.session,defval="0915-1450")
st=time(timeframe.period,s)
e=input(title="END SESSION",type=input.session,defval="1515-1520")
et=time(timeframe.period,e)
quant=input(title="Trade Quantity",defval=1)

//adding stoploss and target option
ut=input(defval=false,title="USE TARGET")
us=input(defval=false,title="USE STOPLOSS")
tar=input(defval=10.0,title="TARGET IN RS")
stop=input(defval=7.0,title="STOP LOSS IN RS")
tar:=tar/syminfo.mintick
stop:=stop/syminfo.mintick

//setting automated alerts required by apibridge
lxse="TYPE: LX" + " :SYMBOL: " + syminfo.ticker + " :QTY: " + tostring(quant) + " :TYPE:SE " + " :SYMBOL: " + syminfo.ticker + " :QTY: " + tostring(quant)

sxle="TYPE: SX" + " :SYMBOL: " + syminfo.ticker + " :QTY: " + tostring(quant) + " :TYPE:LE " + " :SYMBOL: " + syminfo.ticker + " :QTY: " + tostring(quant)

le="TYPE:LE " + " :SYMBOL: " + syminfo.ticker + " :QTY: " + tostring(quant)

lx="TYPE:LX " + " :SYMBOL: " + syminfo.ticker + " :QTY: " + tostring(quant)

se="TYPE:SE " + " :SYMBOL: " + syminfo.ticker + " :QTY: " + tostring(quant)

sx="TYPE:SX " + " :SYMBOL: " + syminfo.ticker + " :QTY: " + tostring(quant)
if(buySignal and st and strategy.position_size==0)
    strategy.entry("BUY",strategy.long,comment=le)
if(sellSignal and st and strategy.position_size==0)
    strategy.entry("SELL",strategy.short,comment=se)
if(buySignal and st and strategy.position_size!=0)
    strategy.entry("BUY",strategy.long,comment=sxle)
if(sellSignal and st and strategy.position_size!=0)
    strategy.entry("SELL",strategy.short,comment=lxse)
    
if(ut==true and us==false)
    strategy.exit(id="LX",from_entry="BUY",profit=tar,comment=lx)
    strategy.exit(id="SX",from_entry="SELL",profit=tar,comment=sx)
if(us==true and ut==false)
    strategy.exit(id="LX",from_entry="BUY",loss=stop,comment=lx)
    strategy.exit(id="SX",from_entry="SELL",loss=stop,comment=sx)
    
if(ut==true and us==true)
    strategy.exit(id="LX",from_entry="BUY",profit=tar,loss=stop,comment=lx)
    strategy.exit(id="SX",from_entry="SELL",profit=tar,loss=stop,comment=sx)
strategy.close(id="BUY",when=et,comment=lx)
strategy.close(id="SELL",when=et,comment=sx)